Import('env')

bb10_lib = [

	'bbutil.c',
	'os_bb10.cpp',
	'audio_driver_bb10.cpp',
	'godot_bb10.cpp',
	'payment_service.cpp',
]

env_bps = env.Clone()
if env['bb10_payment_service'] == "yes":
	env_bps.Append(CPPFLAGS=['-DPAYMENT_SERVICE_ENABLED'])

if env['bb10_lgles_override'] == "yes":
	env_bps.Append(CPPFLAGS=['-DBB10_LGLES_OVERRIDE'])


prog = None
if env["target"]=="release":
	prog = env_bps.Program('#platform/bb10/godot_bb10_opt', bb10_lib)
else:
	prog = env_bps.Program('#platform/bb10/godot_bb10', bb10_lib)

import os
fname = os.path.basename(str(prog[0]))

env.Command('#bin/'+fname, prog, Copy('bin/'+fname, prog[0]))

